<?xml version="1.0" encoding="UTF-8"?>

<!--

Copyright © 2014 František Kučera (frantovo.cz)

This program is free software: you can redistribute it and/or modify

it under the terms of the GNU General Public License as published by

the Free Software Foundation, either version 3 of the License, or

(at your option) any later version.

This program is distributed in the hope that it will be useful,

but WITHOUT ANY WARRANTY; without even the implied warranty of

MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

GNU General Public License for more details.

You should have received a copy of the GNU General Public License

along with this program.  If not, see <http://www.gnu.org/licenses/>.

-->

<xsl:stylesheet version="2.0"

	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

	xmlns:fn="http://www.w3.org/2005/xpath-functions"

	xmlns:h="http://www.w3.org/1999/xhtml">

	<xsl:output method="text" encoding="UTF-8"/>

	<xsl:strip-space elements="*"/>

	<xsl:output method="text" encoding="UTF-8"/>

	<xsl:strip-space elements="*"/>

	<xsl:variable name="urlBase" select="/h:html/h:head/h:base/@href"/>

	<!-- Celý dokument -->

	<xsl:template match="/">

		<xsl:apply-templates select="h:html/h:body"/>

	</xsl:template>

	<xsl:template match="h:h1">

		<xsl:value-of select="text()"/>

		<xsl:text>&#10;</xsl:text>

		<xsl:for-each select="1 to string-length(.)">=</xsl:for-each>		

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:h2">

		<xsl:value-of select="text()"/>

		<xsl:text>&#10;</xsl:text>

		<xsl:for-each select="1 to string-length(.)">-</xsl:for-each>		

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:h3">

		<xsl:for-each select="1 to 3">#</xsl:for-each>

		<xsl:text> </xsl:text>

		<xsl:value-of select="text()"/>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:h4">

		<xsl:for-each select="1 to 4">#</xsl:for-each>

		<xsl:text> </xsl:text>

		<xsl:value-of select="text()"/>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:h5">

		<xsl:for-each select="1 to 5">#</xsl:for-each>

		<xsl:text> </xsl:text>

		<xsl:value-of select="text()"/>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:h6">

		<xsl:for-each select="1 to 6">#</xsl:for-each>

		<xsl:text> </xsl:text>

		<xsl:value-of select="text()"/>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:p">

		<xsl:apply-templates/>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<!--

		TODO: převzít odsazování z hellDesku?

	-->

	<xsl:template match="h:blockquote/h:p">

		<xsl:text>&gt; </xsl:text>

		<xsl:apply-templates/>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:cite[not(matches(., '^(&quot;|„)'))]">

		<xsl:text>„</xsl:text>

		<xsl:apply-templates/>

		<xsl:text>“</xsl:text>

	</xsl:template>	

	<xsl:template match="h:a">

		<xsl:if test="not(text() = @href)">

			<xsl:text>'</xsl:text>

			<xsl:apply-templates select="node()"/>

			<xsl:text>' </xsl:text>

		</xsl:if>

		<xsl:text>&lt;</xsl:text>

		<xsl:choose>

			<xsl:when test="matches(@href, '^(http:|https:|ftp:)')">

				<xsl:value-of select="@href"/>

			</xsl:when>

			<xsl:when test="matches(@href, '^mailto:')">

				<xsl:value-of select="substring-after(@href, 'mailto:')"/>

			</xsl:when>

			<xsl:otherwise>

				<xsl:choose>

					<xsl:when test="ends-with($urlBase, '/') or starts-with(@href, '/')">

						<xsl:value-of select="concat($urlBase, @href)"/>

					</xsl:when>

					<xsl:otherwise>

						<xsl:value-of select="concat($urlBase, '/', @href)"/>

					</xsl:otherwise>

				</xsl:choose>

			</xsl:otherwise>

		</xsl:choose>	

		<xsl:text>&gt;</xsl:text>

		<xsl:if test="@title and not(matches(@title, '^\s*$'))">

			<xsl:text> (</xsl:text>

			<xsl:value-of select="@title"/>

			<xsl:text>)</xsl:text>

		</xsl:if>

	</xsl:template>

	<xsl:template match="h:img">

		<xsl:variable name="obrázek">

			<h:a href="{@src}" title="{@title}">Obrázek: <xsl:value-of select="@alt"/></h:a>

		</xsl:variable>

		<xsl:apply-templates select="$obrázek/node()"/>

	</xsl:template>

	<xsl:template match="h:strong|h:b">

		<xsl:text>**</xsl:text>

		<xsl:apply-templates/>

		<xsl:text>**</xsl:text>

	</xsl:template>

	<xsl:template match="h:em|h:i">

		<xsl:text>*</xsl:text>

		<xsl:apply-templates/>

		<xsl:text>*</xsl:text>

	</xsl:template>

	<xsl:template match="h:abbr[@title]">

		<xsl:apply-templates/>

		<xsl:text> (</xsl:text>

		<xsl:value-of select="@title"/>

		<xsl:text>)</xsl:text>

	</xsl:template>

	<!--

		TODO: převzít odsazování z hellDesku?

	-->

	<xsl:template match="h:pre">

		<xsl:text>--------------------------------</xsl:text>

		<xsl:text>&#10;</xsl:text>

		<xsl:apply-templates/>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>--------------------------------</xsl:text>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:code">

		<xsl:text>`</xsl:text>

		<xsl:apply-templates/>

		<xsl:text>`</xsl:text>

	</xsl:template>

	<xsl:template match="h:hr">

		<xsl:text>----------------------------------------------------------------</xsl:text>

		<xsl:text>&#10;</xsl:text>

		<xsl:text>&#10;</xsl:text>

	</xsl:template>

	<xsl:template match="h:br">

		<xsl:text>&#10;</xsl:text>

	</xsl:template>	

	<xsl:template match="h:ol|h:ul">

		<xsl:variable name="úroveň" select="count(ancestor::h:li)"/>

		<xsl:variable name="odsazení">

			<!-- položky na nejvyšší úrovni odsazené jednou mezerou -->

			<xsl:value-of select="' '"/>

			<xsl:for-each select="2 to $úroveň+1">

				<!-- položky na druhé a vyšší úrovni odsazené vždy dvěma dalšími mezerami -->

				<xsl:value-of select="'  '"/>

			</xsl:for-each>

		</xsl:variable>

		<xsl:if test="$úroveň gt 0">

			<xsl:text>&#10;</xsl:text>

		</xsl:if>

		<xsl:for-each select="h:li">

			<xsl:if test="parent::h:ol"><xsl:value-of select="concat($odsazení, position(), ') ')"/></xsl:if>

			<xsl:if test="parent::h:ul"><xsl:value-of select="concat($odsazení, '- ')"/></xsl:if>

			<xsl:apply-templates/>

			<xsl:if test="$úroveň = 0 or not(position() = last())">

				<xsl:text>&#10;</xsl:text>

			</xsl:if>

		</xsl:for-each>

		<xsl:if test="$úroveň = 0">

			<xsl:text>&#10;</xsl:text>

		</xsl:if>

	</xsl:template>

	<xsl:template match="text()[not(parent::h:pre)]">

		<xsl:if test="matches(., '^\s') and preceding-sibling::node() and not(preceding-sibling::h:br)">

			<xsl:text> </xsl:text>

		</xsl:if>

		<xsl:value-of select="normalize-space(.)"/>

		<xsl:if test="matches(., '\s$') and following-sibling::node()">

			<xsl:text> </xsl:text>

		</xsl:if>

	</xsl:template>

	<xsl:template match="h:div[@class='wwwLinks']">

		<!-- 

			Dvě pomlčky a mezeru budou e-maliloví klienti považovat za začátek podpisu

			a zobrazí ho šedivým písmem a nebudou ho citovat v odpovědích.

		-->

		<xsl:text>-- </xsl:text>

		<xsl:text>&#10;</xsl:text>

		<xsl:apply-templates/>	

	</xsl:template>	

</xsl:stylesheet>