xml-web-generator: šablona/stránka.xsl@860cc8ae1808

     1 <?xml version="1.0" encoding="UTF-8"?>

     2 <xsl:stylesheet version="2.0"

     3 	xmlns="http://www.w3.org/1999/xhtml"

     4 	xmlns:h="http://www.w3.org/1999/xhtml"

     5 	xmlns:s="https://trac.frantovo.cz/xml-web-generator/wiki/xmlns/strana"

     6 	xmlns:k="https://trac.frantovo.cz/xml-web-generator/wiki/xmlns/konfigurace"

     7 	xmlns:m="https://trac.frantovo.cz/xml-web-generator/wiki/xmlns/makro"

     8 	xmlns:j="java:cz.frantovo.xmlWebGenerator.Funkce"

     9 	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

    10 	xmlns:fn="http://www.w3.org/2005/xpath-functions"

    11 	xmlns:svg="http://www.w3.org/2000/svg"

    12 	xmlns:xs="http://www.w3.org/2001/XMLSchema"

    13 	exclude-result-prefixes="fn h s k m j xs">

    14 	<xsl:output

    15 		method="xml"

    16 		indent="yes"

    17 		encoding="UTF-8"

    18 		doctype-public="-//W3C//DTD XHTML 1.1 plus MathML 2.0 plus SVG 1.1//EN"

    19 		doctype-system="http://www.w3.org/2002/04/xhtml-math-svg/xhtml-math-svg.dtd"/>

    21 	<xsl:param name="vstup" select="'../vstup/'"/>

    22 	<xsl:param name="výstup" select="'../výstup/'"/>

    23 	<xsl:param name="vstupníPřípona" select="'.xml'"/>

    24 	<xsl:param name="výstupníPřípona" select="'.xhtml'"/>

    25 	<xsl:param name="vsuvkováPřípona" select="'.inc'"/>

    26 	<xsl:param name="podporaZaostalýchProhlížečů" select="false()" as="xs:boolean"/>

    28 	<xsl:include href="makra.xsl"/>

    30 	<!-- Celý dokument: -->

    31 	<xsl:template match="/">

    32 		<xsl:variable name="konfigurace" select="document(concat($vstup, 'web.conf'))"/>

    33 		<html>

    34 			<head>

    35 				<xsl:if test="$podporaZaostalýchProhlížečů">

    36 					<meta http-equiv="Content-Type" content="application/xhtml+xml; charset=utf-8" />

    37 				</xsl:if>

    38 				<title><xsl:value-of select="s:stránka/s:nadpis"/></title>

    39 				<link title="Novinky (Atom)" href="atom.xml" type="application/atom+xml" rel="alternate"/>

    40 				<link title="Novinky (RSS)"  href="rss.xml"  type="application/rss+xml"  rel="alternate"/>

    41 				<xsl:apply-templates select="$konfigurace/k:web/k:js"/>

    42 				<xsl:apply-templates select="$konfigurace/k:web/k:css"/>

    43 			</head>

    44 			<body>

    45 				<div id="tělo">

    46 					<div id="záhlaví">

    47 						<xsl:apply-templates select="document(fn:encode-for-uri(concat($vstup, 'záhlaví', $vsuvkováPřípona)))/s:stránka/h:text/node()"/>

    48 					</div>

    49 					<div id="vnitřek">

    50 						<h1><xsl:value-of select="s:stránka/s:nadpis"/></h1>

    51 						<ul id="nabídka">

    52 							<xsl:for-each select="collection(concat('./', $vstup ,'/?select=*', $vstupníPřípona))[s:stránka/s:pořadí]">

    53 								<xsl:sort select="empty(./s:stránka/s:pořadí)"/>

    54 								<xsl:sort select="./s:stránka/s:pořadí"/>

    55 								<li>

    56 									<xsl:variable name="xmlSoubor" select="tokenize(document-uri(.), '/')[last()]"/>

    57 									<xsl:variable name="xhtmlSoubor" select="replace($xmlSoubor, $vstupníPřípona, $výstupníPřípona)"/>

    58 									<a href="{fn:encode-for-uri($xhtmlSoubor)}"><xsl:value-of select="./s:stránka/s:nadpis"/></a>

    59 								</li>

    60 							</xsl:for-each>

    61 						</ul>

    62 						<div id="text">

    63 							<xsl:apply-templates select="s:stránka/h:text/node()"/>

    64 						</div>

    65 					</div>

    66 					<div id="zápatí">

    67 						<xsl:apply-templates select="document(fn:encode-for-uri(concat($vstup, 'zápatí', $vsuvkováPřípona)))/s:stránka/h:text/node()"/>

    68 					</div>

    69 				</div>

    70 			</body>

    71 		</html>

    72 	</xsl:template>

    74 	<!-- Kopírujeme elementy, ale vynecháme nepoužité xmlns deklarace: -->

    75 	<xsl:template match="*">

    76 		<xsl:element name="{name()}">

    77 			<xsl:copy-of select="@*"/>

    78 			<xsl:apply-templates/>

    79 		</xsl:element>

    80     </xsl:template>

    82     <!-- Varování pro případ, že jsme v režimu podpory pro zaostalé prohlížeče -->

    83     <xsl:template name="varováníRetardace">

    84     	<xsl:if test="$podporaZaostalýchProhlížečů">

    85 			<xsl:comment>

    86 				Generátor byl spuštěn v režimu podpory zaostalých prohlížečů.

    87 				Uživatelům doporučujeme upgrade na skutečný WWW prohlížeč,

    88 				jako je např. Firefox nebo Chromium (případně Opera či Safari).

    89 			</xsl:comment>

    90     	</xsl:if>

    91     </xsl:template>

    93     <!-- Odkazy na JavaScript a kaskádové styly -->

    94     <xsl:template match="k:web/k:js">

    95     	<script src="{text()}" type="text/javascript">

    96     		<xsl:call-template name="varováníRetardace"/>

    97     	</script>

    98     </xsl:template>

    99     <xsl:template match="k:web/k:css">

   100     	<link href="{text()}" type="text/css" rel="StyleSheet" />

   101     </xsl:template>

   103     <!--

   104     	Makro pro převod interních odkazů:

   105     		- doplnění správné přípony

   106     		- URL kódování znaků

   107     -->

   108     <xsl:template match="m:a">

   109     	<a>

   110     		<xsl:copy-of select="@*"/>

   111     		<xsl:attribute name="href">

   112     			<xsl:value-of select="fn:encode-for-uri(concat(@href, $výstupníPřípona))"/>

   113     		</xsl:attribute>

   114     		<xsl:apply-templates/>

   115     	</a>

   116     </xsl:template>

   118     <!--

   119     	Makro pro zvýraznění syntaxe:

   120     -->

   121     <xsl:template match="m:pre">

   122     	<xsl:variable name="zvýrazněnýText" select="j:zvýrazniSyntaxi(text(), @jazyk)"/>

   123     	<xsl:choose>

   124     		<xsl:when test="$zvýrazněnýText">

   125     			<xsl:comment>Následující kód je v jazyce <xsl:value-of select="@jazyk"/></xsl:comment>

   126     			<xsl:value-of disable-output-escaping="yes" select="$zvýrazněnýText"/>

   127     		</xsl:when>

   128     		<xsl:otherwise>

   129     			<xsl:message>Zvýraznění syntaxe se nezdařilo → bude vložen původní nezvýrazněný kód.</xsl:message>

   130     			<pre><xsl:apply-templates/></pre>

   131     		</xsl:otherwise>

   132     	</xsl:choose>

   133     </xsl:template>

   135     <!--

   136     	Makro pro diagramy/grafy

   137     -->

   138     <xsl:template match="m:diagram">

   139     	<xsl:variable name="souborDiagramu" select="j:vytvořDiagram(text(), @orientace = 'vodorovně')"/>

   140     	<xsl:choose>

   141 			<xsl:when test="$souborDiagramu">

   142 				<div class="diagram">

   143 					<a href="{$souborDiagramu}.svg">

   144 						<img

   145 							src="{$souborDiagramu}.svg"

   146 							alt="Diagram {$souborDiagramu} | pokud nevidíte obrázek, váš prohlížeč stojí za starou bačkoru"

   147 							title="{@nadpis} (klikněte pro zobrazení samotného diagramu)"/>

   148 					</a>

   149 					<!-- TODO: SVG+PNG

   150 					<xsl:variable name="svgDiagramu" select="document(concat($výstup, $souborDiagramu, '.svg'))/svg:svg"/>

   151 					<object

   152 						data="{$souborDiagramu}.svg"

   153 						type="image/svg+xml"

   154 						style="width: {$svgDiagramu/@width}; height: {$svgDiagramu/@height}">

   155 							<img src="{$souborDiagramu}.png" alt="Diagram {$souborDiagramu}"/>

   156 					</object>

   157 					-->

   158 					<xsl:if test="@nadpis">

   159 						<p class="nadpis"><xsl:value-of select="@nadpis"/></p>

   160 					</xsl:if>

   161 				</div>

   162 			</xsl:when>

   163 			<xsl:otherwise>

   164 				<xsl:message terminate="yes">Při vytváření diagramu došlo k chybě.</xsl:message>

   165 			</xsl:otherwise>

   166     	</xsl:choose>

   167     </xsl:template>

   169 </xsl:stylesheet>

author	František Kučera <franta-hg@frantovo.cz>
	Tue, 23 Aug 2011 18:43:44 +0200
changeset 35	860cc8ae1808
parent 33	848da31dd379
child 36	5be21d1ef5f8
permissions	-rw-r--r--