xml-web-generator: šablona/stránka.xsl@487f13126b62

     1 <?xml version="1.0" encoding="UTF-8"?>

     2 <xsl:stylesheet version="2.0"

     3 	xmlns="http://www.w3.org/1999/xhtml"

     4 	xmlns:h="http://www.w3.org/1999/xhtml"

     5 	xmlns:s="https://trac.frantovo.cz/xml-web-generator/wiki/xmlns/strana"

     6 	xmlns:k="https://trac.frantovo.cz/xml-web-generator/wiki/xmlns/konfigurace"

     7 	xmlns:m="https://trac.frantovo.cz/xml-web-generator/wiki/xmlns/makro"

     8 	xmlns:j="java:cz.frantovo.xmlWebGenerator.Funkce"

     9 	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

    10 	xmlns:fn="http://www.w3.org/2005/xpath-functions"

    11 	xmlns:svg="http://www.w3.org/2000/svg"

    12 	xmlns:xs="http://www.w3.org/2001/XMLSchema"

    13 	exclude-result-prefixes="fn h s k m j xs">

    14 	<xsl:output

    15 		method="xml"

    16 		indent="yes"

    17 		encoding="UTF-8"

    18 		doctype-public="-//W3C//DTD XHTML 1.1 plus MathML 2.0 plus SVG 1.1//EN"

    19 		doctype-system="http://www.w3.org/2002/04/xhtml-math-svg/xhtml-math-svg.dtd"/>

    21 	<xsl:param name="vstup" select="'../vstup/'"/>

    22 	<xsl:param name="výstup" select="'../výstup/'"/>

    23 	<xsl:param name="vstupníPřípona" select="'.xml'"/>

    24 	<xsl:param name="výstupníPřípona" select="'.xhtml'"/>

    25 	<xsl:param name="vsuvkováPřípona" select="'.inc'"/>

    26 	<xsl:param name="podporaZaostalýchProhlížečů" select="false()" as="xs:boolean"/>

    28 	<xsl:include href="makra.xsl"/>

    30 	<!-- Celý dokument: -->

    31 	<xsl:template match="/">

    32 		<xsl:variable name="konfigurace" select="document(concat($vstup, 'web.conf'))"/>

    33 		<html>

    34 			<head>

    35 				<xsl:if test="$podporaZaostalýchProhlížečů">

    36 					<meta http-equiv="Content-Type" content="application/xhtml+xml; charset=utf-8" />

    37 				</xsl:if>

    38 				<title><xsl:value-of select="s:stránka/s:nadpis"/></title>

    39 				<link title="Novinky (Atom)" href="atom.xml" type="application/atom+xml" rel="alternate"/>

    40 				<link title="Novinky (RSS)"  href="rss.xml"  type="application/rss+xml"  rel="alternate"/>

    41 				<xsl:apply-templates select="$konfigurace/k:web/k:js"/>

    42 				<xsl:apply-templates select="$konfigurace/k:web/k:css"/>

    43 			</head>

    44 			<body>

    45 				<div id="tělo">

    46 					<div id="záhlaví">

    47 						<xsl:apply-templates select="document(fn:encode-for-uri(concat($vstup, 'záhlaví', $vsuvkováPřípona)))/s:stránka/h:text/node()"/>

    48 					</div>

    49 					<div id="vnitřek">

    50 						<h1><xsl:value-of select="s:stránka/s:nadpis"/></h1>

    51 						<ul id="nabídka">

    52 							<xsl:for-each select="collection(concat('./', $vstup ,'/?select=*', $vstupníPřípona))[s:stránka/s:pořadí]">

    53 								<xsl:sort select="empty(./s:stránka/s:pořadí)"/>

    54 								<xsl:sort select="./s:stránka/s:pořadí"/>

    55 								<li>

    56 									<xsl:variable name="xmlSoubor" select="tokenize(document-uri(.), '/')[last()]"/>

    57 									<xsl:variable name="xhtmlSoubor" select="replace($xmlSoubor, $vstupníPřípona, $výstupníPřípona)"/>

    58 									<a href="{fn:encode-for-uri($xhtmlSoubor)}"><xsl:value-of select="./s:stránka/s:nadpis"/></a>

    59 								</li>

    60 							</xsl:for-each>

    61 						</ul>

    62 						<div id="text">

    63 							<xsl:apply-templates select="s:stránka/h:text/node()"/>

    64 						</div>

    65 					</div>

    66 					<div id="zápatí">

    67 						<xsl:apply-templates select="document(fn:encode-for-uri(concat($vstup, 'zápatí', $vsuvkováPřípona)))/s:stránka/h:text/node()"/>

    68 					</div>

    69 				</div>

    70 			</body>

    71 		</html>

    72 	</xsl:template>

    74 	<!-- Kopírujeme elementy, ale vynecháme nepoužité xmlns deklarace: -->

    75 	<xsl:template match="*">

    76 		<xsl:element name="{name()}">

    77 			<xsl:copy-of select="@*"/>

    78 			<xsl:apply-templates/>

    79 		</xsl:element>

    80     </xsl:template>

    82     <!-- Varování pro případ, že jsme v režimu podpory pro zaostalé prohlížeče -->

    83     <xsl:template name="varováníRetardace">

    84     	<xsl:if test="$podporaZaostalýchProhlížečů">

    85 			<xsl:comment>

    86 				Generátor byl spuštěn v režimu podpory zaostalých prohlížečů.

    87 				Uživatelům doporučujeme upgrade na skutečný WWW prohlížeč,

    88 				jako je např. Firefox nebo Chromium (případně Opera či Safari).

    89 			</xsl:comment>

    90     	</xsl:if>

    91     </xsl:template>

    93     <!-- Odkazy na JavaScript a kaskádové styly -->

    94     <xsl:template match="k:web/k:js">

    95     	<script src="{text()}" type="text/javascript">

    96     		<xsl:call-template name="varováníRetardace"/>

    97     	</script>

    98     </xsl:template>

    99     <xsl:template match="k:web/k:css">

   100     	<link href="{text()}" type="text/css" rel="StyleSheet" />

   101     </xsl:template>

   103     <!--

   104     	TODO: makra vyčlenit do samostatných souborů

   105     -->

   107     <!--

   108     	Makro pro převod interních odkazů:

   109     		- doplnění správné přípony

   110     		- URL kódování znaků

   111     -->

   112     <xsl:template match="m:a">

   113     	<a>

   114     		<xsl:copy-of select="@*"/>

   115     		<xsl:attribute name="href">

   116     			<xsl:value-of select="fn:encode-for-uri(concat(@href, $výstupníPřípona))"/>

   117     		</xsl:attribute>

   118     		<xsl:apply-templates/>

   119     	</a>

   120     </xsl:template>

   122     <!--

   123     	Makro pro zvýraznění syntaxe:

   124     -->

   125     <xsl:template match="m:pre">

   126     	<xsl:call-template name="vypišPre">

   127     		<xsl:with-param name="zvýrazněnýText" select="j:zvýrazniSyntaxi(text(), @jazyk)"/>

   128     	</xsl:call-template>

   129     </xsl:template>

   131     <xsl:template match="m:pre[@src]">

   132     	<xsl:call-template name="vypišPre">

   133     		<xsl:with-param name="zvýrazněnýText" select="j:zvýrazniSyntaxiSouboru(@src, @jazyk)"/>

   134     	</xsl:call-template>

   135     </xsl:template>

   137     <xsl:template name="vypišPre">

   138     	<xsl:param name="zvýrazněnýText"/>

   139     	<xsl:choose>

   140     		<xsl:when test="$zvýrazněnýText">

   141     			<xsl:comment>Následující kód je v jazyce <xsl:value-of select="@jazyk"/></xsl:comment>

   142     			<xsl:value-of disable-output-escaping="yes" select="$zvýrazněnýText"/>

   143     		</xsl:when>

   144     		<xsl:otherwise>

   145     			<xsl:message>Zvýraznění syntaxe se nezdařilo → bude vložen původní nezvýrazněný kód.</xsl:message>

   146     			<pre><xsl:apply-templates/></pre>

   147     		</xsl:otherwise>

   148     	</xsl:choose>

   149     </xsl:template>

   151     <!--

   152     	Makro pro diagramy/grafy

   153     -->

   154     <xsl:template match="m:diagram">

   155     	<xsl:variable name="souborDiagramu" select="j:vytvořDiagram(text(), @orientace = 'vodorovně')"/>

   156     	<xsl:choose>

   157 			<xsl:when test="$souborDiagramu">

   158 				<div class="diagram">

   159 					<a href="{$souborDiagramu}.svg">

   160 						<img

   161 							src="{$souborDiagramu}.svg"

   162 							alt="Diagram {$souborDiagramu} | pokud nevidíte obrázek, váš prohlížeč stojí za starou bačkoru"

   163 							title="{@nadpis} (klikněte pro zobrazení samotného diagramu)"/>

   164 					</a>

   165 					<!-- TODO: SVG+PNG

   166 					<xsl:variable name="svgDiagramu" select="document(concat($výstup, $souborDiagramu, '.svg'))/svg:svg"/>

   167 					<object

   168 						data="{$souborDiagramu}.svg"

   169 						type="image/svg+xml"

   170 						style="width: {$svgDiagramu/@width}; height: {$svgDiagramu/@height}">

   171 							<img src="{$souborDiagramu}.png" alt="Diagram {$souborDiagramu}"/>

   172 					</object>

   173 					-->

   174 					<xsl:if test="@nadpis">

   175 						<p class="nadpis"><xsl:value-of select="@nadpis"/></p>

   176 					</xsl:if>

   177 				</div>

   178 			</xsl:when>

   179 			<xsl:otherwise>

   180 				<xsl:message terminate="yes">Při vytváření diagramu došlo k chybě.</xsl:message>

   181 			</xsl:otherwise>

   182     	</xsl:choose>

   183     </xsl:template>

   185     <!--

   186     	Makro pro Wiki syntaxi

   187     -->

   188     <xsl:template match="m:wiki">

   189     	<xsl:variable name="wikiXHTML" select="j:formátujWiki(text(), @syntaxe)"/>

   190     	<xsl:choose>

   191 			<xsl:when test="$wikiXHTML">

   192 				<xsl:value-of select="$wikiXHTML" disable-output-escaping="yes"/>

   193 			</xsl:when>

   194 			<xsl:otherwise>

   195 				<xsl:message terminate="yes">Při zpracování wiki syntaxe došlo k chybě.</xsl:message>

   196 			</xsl:otherwise>

   197 		</xsl:choose>

   198     </xsl:template>

   200 </xsl:stylesheet>

author	František Kučera <franta-hg@frantovo.cz>
	Sat, 31 Dec 2011 17:52:21 +0100
changeset 40	487f13126b62
parent 37	2e4e7891a2f7
child 41	035e690ce9c6
permissions	-rw-r--r--