| author | insilmaril |
| Wed, 24 Oct 2007 12:21:24 +0000 | |
| changeset 613 | 8fb5b3956b3e |
| parent 608 | 6cdc2e7b1937 |
| child 620 | 24bfecc949a0 |
| permissions | -rw-r--r-- |
1 TEMPLATE = app
2 LANGUAGE = C++
4 CONFIG += qt warn_on release debug
5 CONFIG += x86 ppc
7 # Manifest embedding was suggested by Qt docs somewhere...
8 win32: CONFIG += embed_manifest_exe
10 # Without this, M_PI, and M_PI_2 won't be defined.
11 win32:DEFINES *= _USE_MATH_DEFINES
13 ICON =icons/vym.icns
15 QT += qt3support
16 QT += network
18 HEADERS += \
19 aboutdialog.h \
20 animpoint.h \
21 branchobj.h \
22 branchpropwindow.h\
23 editxlinkdialog.h \
24 exportoofiledialog.h \
25 exportxhtmldialog.h\
26 exports.h \
27 extrainfodialog.h \
28 file.h \
29 findwindow.h \
30 flagobj.h \
31 flagrowobj.h \
32 floatimageobj.h \
33 floatobj.h \
34 frameobj.h \
35 headingobj.h \
36 highlighter.h \
37 historywindow.h \
38 imageobj.h \
39 imports.h \
40 linkablemapobj.h \
41 xlinkobj.h \
42 mainwindow.h \
43 mapcenterobj.h \
44 mapeditor.h \
45 mapobj.h \
46 misc.h \
47 noteobj.h \
48 options.h \
49 ornamentedobj.h \
50 parser.h \
51 process.h \
52 selection.h \
53 showtextdialog.h\
54 simplescripteditor.h\
55 texteditor.h \
56 version.h \
57 xml-base.h \
58 xml-vym.h \
59 xml-freemind.h \
60 xsltproc.h \
61 settings.h \
62 warningdialog.h
64 SOURCES += \
65 aboutdialog.cpp \
66 animpoint.cpp \
67 branchobj.cpp \
68 branchpropwindow.cpp \
69 editxlinkdialog.cpp \
70 exportoofiledialog.cpp \
71 exports.cpp \
72 exportxhtmldialog.cpp \
73 extrainfodialog.cpp \
74 file.cpp \
75 findwindow.cpp \
76 flagobj.cpp \
77 flagrowobj.cpp \
78 floatimageobj.cpp \
79 floatobj.cpp \
80 frameobj.cpp \
81 headingobj.cpp \
82 highlighter.cpp \
83 historywindow.cpp \
84 imageobj.cpp \
85 imports.cpp \
86 linkablemapobj.cpp \
87 xlinkobj.cpp \
88 main.cpp \
89 mainwindow.cpp \
90 mapcenterobj.cpp \
91 mapeditor.cpp \
92 mapobj.cpp \
93 misc.cpp \
94 noteobj.cpp \
95 options.cpp \
96 ornamentedobj.cpp \
97 parser.cpp \
98 process.cpp \
99 selection.cpp \
100 showtextdialog.cpp \
101 simplescripteditor.cpp \
102 texteditor.cpp \
103 version.cpp \
104 xml-base.cpp \
105 xml-vym.cpp \
106 xml-freemind.cpp \
107 xsltproc.cpp \
108 settings.cpp \
109 warningdialog.cpp
111 FORMS = \
112 branchpropwindow.ui \
113 exportxhtmldialog.ui \
114 extrainfodialog.ui \
115 editxlinkdialog.ui \
116 historywindow.ui \
117 simplescripteditor.ui \
118 showtextdialog.ui \
119 warningdialog.ui
121 #The following lines were inserted by qt3to4
122 QT += xml
124 TARGET = vym
126 TRANSLATIONS += lang/vym_de.ts
127 TRANSLATIONS += lang/vym_en.ts
128 TRANSLATIONS += lang/vym_es.ts
129 TRANSLATIONS += lang/vym_it.ts
131 isEmpty( PREFIX ) {
132 PREFIX = /usr/local
133 count( INSTALLDIR, 1 ) {
134 PREFIX = $${INSTALLDIR}
135 message( "Please use PREFIX instead of INSTALLDIR" )
136 }
137 }
138 isEmpty( BINDIR ) {
139 BINDIR = $${PREFIX}/bin
140 }
141 isEmpty( DATADIR ) {
142 DATADIR = $${PREFIX}/share
143 }
144 isEmpty( DOCDIR ) {
145 DOCDIR = $${DATADIR}/doc/packages/vym
146 }
147 isEmpty( DEMODIR ) {
148 DEMODIR = $${DOCDIR}
149 }
151 message( "Installation directory" )
152 message( $$PREFIX )
155 target.path = $${BINDIR}
156 INSTALLS += target
158 support.files = styles/ scripts/ icons/ flags/ lang/ macros/ exports/
159 support.path = $${DATADIR}/vym
160 INSTALLS += support
162 doc.files = tex/vym.pdf
163 doc.path = $${DOCDIR}
164 INSTALLS += doc
165 DEFINES += VYM_DOCDIR=\\\"$${DOCDIR}\\\"
167 demo.files = demos/
168 demo.path = $${DEMODIR}
169 INSTALLS += demo