TEMPLATE	= app

LANGUAGE	= C++

CONFIG	+= qt warn_on debug

CONFIG += x86 ppc

CONFIG += qdbus

include (/data/qtanimationframework-2.3-opensource/src/gui-animation.pri)

include (/data/qtanimationframework-2.3-opensource/src/corelib-animation.pri)

include (/data/qtanimationframework-2.3-opensource/src/qtanimationframework.pri)

TRANSLATIONS += lang/vym_de.ts

TRANSLATIONS += lang/vym_en.ts

TRANSLATIONS += lang/vym_es.ts

TRANSLATIONS += lang/vym_it.ts

TRANSLATIONS += lang/vym_fr.ts

TRANSLATIONS += lang/vym_zh_CN.ts

TRANSLATIONS += lang/vym_pt_BR.ts

TRANSLATIONS += lang/vym_sv.ts

TRANSLATIONS += lang/vym_zh_TW.ts

# Manifest embedding was suggested by Qt docs somewhere...

win32: CONFIG += embed_manifest_exe

# Without this, M_PI, and M_PI_2 won`t be defined.

win32:DEFINES *= _USE_MATH_DEFINES

ICON =icons/vym.icns

QT += qt3support

QT += network

HEADERS	+= \

	aboutdialog.h \

	adaptormodel.h \

	animpoint.h \

	attribute.h \

	attributeitem.h \

#	attributedelegate.h\

#	attributedialog.h \

#	attributewidget.h \

	branchitem.h \

	branchobj.h \

	branchpropwindow.h\

	editxlinkdialog.h \

	exportoofiledialog.h \

	exportxhtmldialog.h\

	exports.h \

	extrainfodialog.h \

	file.h \

	findwindow.h \

	flag.h \

	flagobj.h \

	flagrowobj.h \

	flagrow.h \

	floatimageobj.h \

	floatobj.h \

	frameobj.h \

	geometry.h \

	headingobj.h \

	highlighter.h \

	historywindow.h \

	imageitem.h \

	imageobj.h \

	imports.h \

	linkablemapobj.h \

	mainwindow.h \

	mapeditor.h \

	mapitem.h \

	mapobj.h \

	misc.h \

	mysortfilterproxymodel.h \

	noteobj.h \

	options.h \

	ornamentedobj.h \

	parser.h \

	process.h \

	showtextdialog.h\

	simplescripteditor.h\

	texteditor.h \

	treeeditor.h \

	version.h \

	vymmodel.h \

	xlinkitem.h \

	xlinkobj.h \

	xml-base.h \

	xml-vym.h \

	xml-freemind.h \

	xmlobj.h\

	xsltproc.h \

	settings.h \

	treeitem.h \

	treemodel.h \

	vymview.h \

	warningdialog.h

SOURCES	+= \

	aboutdialog.cpp \

	adaptormodel.cpp \

	animpoint.cpp \

	attribute.cpp \

	attributeitem.cpp \

#	attributedelegate.cpp \

#	attributedialog.cpp \

#	attributewidget.cpp \

	branchitem.cpp \

	branchobj.cpp \

	branchpropwindow.cpp \

	editxlinkdialog.cpp \

	exportoofiledialog.cpp \

	exports.cpp \

	exportxhtmldialog.cpp \

	extrainfodialog.cpp \

	file.cpp \

	findwindow.cpp \

	flag.cpp \

	flagobj.cpp \

	flagrow.cpp \

	flagrowobj.cpp \

	floatimageobj.cpp \

	floatobj.cpp \

	frameobj.cpp \

	geometry.cpp \

	headingobj.cpp \

	highlighter.cpp \

	historywindow.cpp \

	imageitem.cpp \

	imageobj.cpp \

	imports.cpp \

	linkablemapobj.cpp \

	main.cpp \

	mainwindow.cpp \

	mapeditor.cpp \

	mapitem.cpp \

	mapobj.cpp \

	misc.cpp \

	mysortfilterproxymodel.cpp \

	noteobj.cpp \

	options.cpp \

	ornamentedobj.cpp \

	parser.cpp \

	process.cpp \

	showtextdialog.cpp \

	simplescripteditor.cpp \

	texteditor.cpp \

	treeeditor.cpp \

	treeitem.cpp \

	treemodel.cpp \

	version.cpp \

	vymmodel.cpp \

	xlinkitem.cpp \

	xlinkobj.cpp \

	xml-base.cpp \

	xml-vym.cpp \

	xml-freemind.cpp \

	xmlobj.cpp \

	xsltproc.cpp \

	settings.cpp \

	vymview.cpp \

	warningdialog.cpp

FORMS = \

	attributewidget.ui \

	branchpropwindow.ui \

	exportxhtmldialog.ui \

	extrainfodialog.ui \

	editxlinkdialog.ui \

	historywindow.ui \

	simplescripteditor.ui \

	showtextdialog.ui \

	warningdialog.ui

win32 {

	HEADERS += mkdtemp.h

	SOURCES += mkdtemp.cpp

	RC_FILE = vym.rc

}

#The following lines were inserted by qt3to4

QT += xml

TARGET  = vym

isEmpty( PREFIX ) {

	PREFIX = /usr/local

	count( INSTALLDIR, 1 ) {

		PREFIX = $${INSTALLDIR}

		message( "Please use PREFIX instead of INSTALLDIR" )

	}

}

isEmpty( BINDIR ) {

	BINDIR = $${PREFIX}/bin

}

isEmpty( DATADIR ) {

	DATADIR = $${PREFIX}/share

}

isEmpty( DOCDIR ) {

	DOCDIR = $${DATADIR}/doc/packages/vym

}

message( "Installation directory" )

message( $$PREFIX )

target.path = $${BINDIR}

INSTALLS += target

support.files = styles/ scripts/ icons/ flags/ lang/ macros/ exports/ demos/

support.path = $${DATADIR}/vym

INSTALLS += support 

doc.files = doc/vym.pdf

doc.path = $${DOCDIR}

INSTALLS += doc

DEFINES += VYM_DOCDIR=\\\"$${DOCDIR}\\\"

include(test/modeltest/modeltest.pri)