diff -r cbf1a1153313 -r c60625d58158 helpers/mimeTextPart.xsl
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/helpers/mimeTextPart.xsl	Mon Oct 17 18:14:34 2011 +0200
@@ -0,0 +1,199 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet version="2.0"
+	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+	xmlns:fn="http://www.w3.org/2005/xpath-functions"
+	xmlns:h="http://www.w3.org/1999/xhtml">
+	<xsl:output method="text" encoding="UTF-8"/>
+	<xsl:strip-space elements="*"/>
+	
+	<xsl:output method="text" encoding="UTF-8"/>
+	<xsl:strip-space elements="*"/>
+	
+	<xsl:variable name="urlBase" select="/h:html/h:head/h:base/@href"/>
+	
+	<!-- Celý dokument -->
+	<xsl:template match="/">
+		<xsl:apply-templates select="h:html/h:body"/>
+	</xsl:template>
+
+	<xsl:template match="h:h1">
+		<xsl:value-of select="text()"/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:for-each select="1 to string-length(.)">#</xsl:for-each>		
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:h2">
+		<xsl:value-of select="text()"/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:for-each select="1 to string-length(.)">-</xsl:for-each>		
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:h3">
+		<xsl:for-each select="1 to 3">#</xsl:for-each>
+		<xsl:text> </xsl:text>
+		<xsl:value-of select="text()"/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+
+	
+	<xsl:template match="h:h4">
+		<xsl:for-each select="1 to 4">#</xsl:for-each>
+		<xsl:text> </xsl:text>
+		<xsl:value-of select="text()"/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+
+	
+	<xsl:template match="h:h5">
+		<xsl:for-each select="1 to 5">#</xsl:for-each>
+		<xsl:text> </xsl:text>
+		<xsl:value-of select="text()"/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:h6">
+		<xsl:for-each select="1 to 6">#</xsl:for-each>
+		<xsl:text> </xsl:text>
+		<xsl:value-of select="text()"/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+
+
+	<xsl:template match="h:p">
+		<xsl:apply-templates/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:a">
+		<xsl:text>"</xsl:text>
+		<xsl:value-of select="text()"/>
+		<xsl:text>" &lt;</xsl:text>
+		<xsl:choose>
+			<xsl:when test="matches(@href, '^(http:|https:|ftp:)')">
+				<xsl:value-of select="@href"/>
+			</xsl:when>
+			<xsl:when test="matches(@href, '^mailto:')">
+				<xsl:value-of select="substring-after(@href, 'mailto:')"/>
+			</xsl:when>
+			<xsl:otherwise>
+				<xsl:choose>
+					<xsl:when test="ends-with($urlBase, '/') or starts-with(@href, '/')">
+						<xsl:value-of select="concat($urlBase, @href)"/>
+					</xsl:when>
+					<xsl:otherwise>
+						<xsl:value-of select="concat($urlBase, '/', @href)"/>
+					</xsl:otherwise>
+				</xsl:choose>
+			</xsl:otherwise>
+		</xsl:choose>	
+		<xsl:text>&gt;</xsl:text>
+		<xsl:if test="@title and not(matches(@title, '^\s*$'))">
+			<xsl:text> (</xsl:text>
+			<xsl:value-of select="@title"/>
+			<xsl:text>)</xsl:text>
+		</xsl:if>
+	</xsl:template>
+	
+	<xsl:template match="h:img">
+		<xsl:variable name="obrázek">
+			<h:a href="{@src}" title="{@title}">Obrázek: <xsl:value-of select="@alt"/></h:a>
+		</xsl:variable>
+		<xsl:apply-templates select="$obrázek/node()"/>
+	</xsl:template>
+	
+	<xsl:template match="h:strong|h:b">
+		<xsl:text>**</xsl:text>
+		<xsl:apply-templates/>
+		<xsl:text>**</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:em|h:i">
+		<xsl:text>*</xsl:text>
+		<xsl:apply-templates/>
+		<xsl:text>*</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:abbr[@title]">
+		<xsl:apply-templates/>
+		<xsl:text> (</xsl:text>
+		<xsl:value-of select="@title"/>
+		<xsl:text>)</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:pre">
+		<xsl:text>--------------------------------</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:apply-templates/>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>--------------------------------</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:code">
+		<xsl:text>`</xsl:text>
+		<xsl:apply-templates/>
+		<xsl:text>`</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:hr">
+		<xsl:text>----------------------------------------------------------------</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:ul">
+		<xsl:apply-templates/>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:ul/h:li">
+		<xsl:text> - </xsl:text>
+		<xsl:apply-templates/>
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	<xsl:template match="h:ol">
+		<xsl:for-each select="h:li">
+			<xsl:value-of select="concat(' ', position(), ') ')"/>
+			<xsl:apply-templates/>
+			<xsl:text>&#10;</xsl:text>
+		</xsl:for-each>		
+		<xsl:text>&#10;</xsl:text>
+	</xsl:template>
+	
+	
+	<!--
+	<xsl:template match="h:blockquote[matches(p/text(), '^(\"|„)')]">
+		
+	</xsl:template>
+	-->
+	
+	<xsl:template match="text()[not(parent::h:pre)]">
+		<xsl:if test="matches(., '^\s')">
+			<xsl:text> </xsl:text>
+		</xsl:if>
+		<xsl:value-of select="normalize-space(.)"/>
+		<xsl:if test="matches(., '\s$')">
+			<xsl:text> </xsl:text>
+		</xsl:if>
+	</xsl:template>
+
+	
+	<xsl:template match="h:div[@class='wwwLinks']">
+		<xsl:text>-- </xsl:text>
+		<xsl:text>&#10;</xsl:text>
+		<xsl:apply-templates/>	
+	</xsl:template>	
+
+
+</xsl:stylesheet>